// motor keys V014.
// by: gijs gieskes.
// script for use with arduino V12.

#include <EEPROM.h>

int multiPinIn = 3;

//digi pot vars
#define DATAOUT 11 //MOSI
#define DATAIN 12 //MISO - not used, but part of builtin SPI
#define SPICLOCK  13 //sck
#define SLAVESELECT 10 //ss
byte pot=0;
byte pots0 = B00000000;
byte pots1 = B00010000;
byte resistance=0;

int analogVal0;
int analogVal1;

float sinA[] = {1, 0.989, 0.961, 0.917, 0.858, 0.787, 0.707, 0.62, 0.531, 0.442, 0.358, 0.281, 0.215, 0.163, 0.125, 0.104, 0.101, 0.115, 0.147, 0.195, 0.256, 0.329, 0.411, 0.499, 0.55, 0.639, 0.724, 0.803, 0.872, 0.927, 0.968, 0.993};
float sinB[] = {0.5, 0.599, 0.694, 0.781, 0.857, 0.919, 0.965, 0.992, 1, 0.988, 0.957, 0.907, 0.842, 0.763, 0.674, 0.578, 0.479, 0.38, 0.287, 0.202, 0.128, 0.069, 0.028, 0.005, 0.001, 0.017, 0.052, 0.105, 0.174, 0.255, 0.346, 0.443};
byte indexSinAM = 0;
byte indexSinVib = 0;

// timer / "interupt" variables
long previousMillis = 0;
long interval = 64;

// AM
long previousMillisAM = 0;
byte intervalAM = 12;
byte volumeAM = 128;

// Vibrato
long previousMillisVib = 0;
byte intervalVib = 20;
byte depthVib = 50;
float depthVibFloat = 0.2;

// multiplex variables
boolean multiArray[16] = {HIGH,HIGH,HIGH,HIGH,
                          HIGH,HIGH,HIGH,HIGH,
                          HIGH,HIGH,HIGH,HIGH,
                          HIGH,HIGH,HIGH,HIGH
                          };

byte recKeysPin = 12;
int volume = 255;
int volumeOut = 255;
byte ADSR = 0;

//output naar motor
byte outputStorage = 0;
byte keyboardVal = 0;
byte motorPin = 9;

//eeprom pin
boolean loadState = 0;
boolean storeState = 0;
byte LEDpin = 8;

//keyboardSelector
byte keySelect = 0;

//keyboard values
byte keysArr[2][12] = {
                      {79,95,111,135,143,160,173,187,197,208,226,239},
                      {79,95,111,135,143,160,173,187,197,208,226,239}
                      };

void setup(){
  //digi pot vars
  byte clr;
  pinMode(DATAOUT, OUTPUT);
  pinMode(DATAIN, INPUT);
  pinMode(SPICLOCK,OUTPUT);
  pinMode(SLAVESELECT,OUTPUT);
  digitalWrite(SLAVESELECT,HIGH); //disable device
  SPCR = (1<<SPE)|(1<<MSTR);
  clr=SPSR;
  clr=SPDR;
  delay(10);
  for(byte i=0;i<2;i++){
    write_pot(i,255);
  }

  pinMode(recKeysPin, INPUT);
  digitalWrite(recKeysPin, HIGH);
  
  pinMode(motorPin, OUTPUT);

  //pin 7,6,5,4 zijn nu outputs;
  DDRD = DDRD | B11110000;

  pinMode(multiPinIn, INPUT);
  digitalWrite(multiPinIn, HIGH);
  
  //LED
  pinMode(LEDpin, OUTPUT);
  digitalWrite(LEDpin, HIGH);
  //Serial.begin(9600);
}

void loop(){
   
  analogVal0 = analogRead(0);
  analogVal1 = analogRead(1);
  
  ADSR = 0;
  for(byte i=0; i<12; i++){
    if(multiArray[i] == LOW){
      ADSR = 1;
      keyboardVal = keysArr[keySelect][i];
      vibratoFunction();
      analogWrite(motorPin, outputStorage);
      //sla een nieuwe keyboard speed op 
      if(multiArray[12] == LOW){
        byte val = map(analogVal0, 0, 1023, 0, 165); //vreemde waarde omdat deze later geinvert wordt..
        keysArr[keySelect][i] = val;
        //Serial.println(val, DEC);
      }
      break; //breaks the for loop, anders kun je twee toetsen in duwen.
    }
  }
  
  if(multiArray[15] == LOW){
    if(multiArray[7] == LOW){
      intervalAM = analogVal1/16;        // AM rate
      volumeAM = analogVal0/4;           // AM depth 
    }
    if(multiArray[6] == LOW){
      intervalVib = analogVal1/16; 
      depthVib = analogVal0/4;       // AM depth 
    }
  }

  //store in eeprom
  store();
  load();
  
  keyboardSelect();
  readButtons();
  delayFunction();
  AMFunction();
  
  //output to potmeter
  volumeOut = max(volumeOut,0);
  volumeOut = min(volumeOut,255);
  
  //write volume to LED and DIGIpot.
  write_pot(pots0, volumeOut);
  write_pot(pots1, volumeOut);
  
  //Serial.println(volumeOut, DEC);
  
  //delay zomaar..
  delay(1);
}

//lees de multiplex buttons in
void readButtons(){
  int shifter = 0;
  for(byte i=0; i<16; i++){
    shifter = (i<<4);
    PORTD &= B00001111;
    PORTD |= shifter; //schijf naar poort 7,6,5,4 
    //Serial.println(PORTD, BIN);
    delayMicroseconds(3); //als deze delay er niet is, leest hij om en om waarde in.. waarschijnlijk debounce
    multiArray[i] = digitalRead(multiPinIn);
  }
}

void keyboardSelect(){
  if(multiArray[14] == LOW){
    keySelect = 0;
  }else{
    keySelect = 1;
  }
}

void AMFunction(){
  if(millis() - previousMillisAM > intervalAM) {
    previousMillisAM = millis();
    
    if(multiArray[13] == LOW || indexSinAM != 0){     
      if(indexSinAM<31){
        indexSinAM++;
      }else{
        indexSinAM = 0;
      }
      
      byte volumeTemp = 255 - volumeAM;
      volumeOut = (volume*sinA[indexSinAM])+volumeTemp;
      volumeOut = min(volumeOut, volume);   
    }else{
      indexSinAM = 0;
      volumeOut = volume;
    }
  }
}

void delayFunction(){
  if (millis() - previousMillis > interval) {
    previousMillis = millis();
    
    if(ADSR == 1){
      if(volume < 255){
        volume += analogVal0*0.1;
      }
      volume = min(volume, 255);
    }else{
      if(volume > 1){
        volume -= analogVal1*0.1;
      }
      volume = max(volume, 0);
    }
  }
}

// digi pots write
byte write_pot(int address, int value){
  digitalWrite(SLAVESELECT,LOW);
  //2 byte opcode
  spi_transfer(address);
  spi_transfer(value);
  digitalWrite(SLAVESELECT,HIGH);
}

//digipot transfer
char spi_transfer(volatile char data){
  SPDR = data;
  while (!(SPSR & (1<<SPIF))) 
  {
  };
  return SPDR;
}

void load(){
  
  if(multiArray[15] == LOW && multiArray[11] == LOW){
    int address = 0;
  
    //schrijf de variables
    for(byte i = 0; i < 2; i++){ 
      for(byte j=0; j<12; j++){
        keysArr[i][j] = EEPROM.read(address);
        address++;
      }
    }
    intervalAM = EEPROM.read(address);
    address++; 
    volumeAM = EEPROM.read(address);
    address++;
    intervalVib = EEPROM.read(address);
    address++;
    depthVib = EEPROM.read(address);

    ledBlink(1);
  }
}

void store(){
  
  if(multiArray[15] == LOW && multiArray[9] == LOW){
    int address = 0;
    
    //schrijf de variables
    for(byte i = 0; i < 2; i++){ 
      for(byte j=0; j<12; j++){
        EEPROM.write(address, keysArr[i][j]);
        address++;
      }
    }
    EEPROM.write(address, intervalAM);
    address++;
    EEPROM.write(address, volumeAM);
    address++;
    EEPROM.write(address, intervalVib);
    address++;
    EEPROM.write(address, depthVib);

    ledBlink(2);
  }
}

byte ledBlink(byte amount){
  boolean onOff = HIGH;
  amount*=2;
  for(byte a=0; a<amount; a++){
    onOff = !onOff;
    digitalWrite(LEDpin, onOff);
    delay(500);
  }
}

void vibratoFunction(){
  
  if(multiArray[13] == LOW){
    depthVibFloat = depthVib*0.0039;
    outputStorage = 255 - (keyboardVal*(1 - (depthVibFloat*sinB[indexSinVib]))); //what a mess.. 
  }else{
    outputStorage = 255 - keyboardVal; //inverse.. stom van me.. 
  }
  if(millis() - previousMillisVib > intervalVib) {
    previousMillisVib = millis();
    
    if(indexSinVib<31){
      indexSinVib++;
    }else{
      indexSinVib = 0;
    }
  }
}